Outils pour utilisateurs

Outils du site


Discussion logiciels:exiftool

ExifTool est un outil multi-platerforme et purement en ligne de commande quasiment incontournable dès qu'il est question de métadonnées de fichiers images et souvent utilisé comme base par les logiciels plus évolués pour y accéder et/ou les modifier.

Dans mon cas, je l'ai découvert parce qu'il est installé (et régulièrement mis à jour) par GeoSetter, d'où le chemin d'accès spécifique à l'exécutable dans les commandes ci-dessous qu'il faudra éventuellement adapter à vos besoin si vous installez Exiftool manuellement.

Notez que pour de nombreux formats d'images RAW, même si ExifTool les connait, il n'est pas capable de les modifier directement et ajoute à côté d'eux un fichier .xmp dans lequel les métadonnées sont intégrées. Ces fichiers, qui portent le même nom que l'image, sont bien connus des logiciels de traitement d'images et il suffit de les conserver avec leur image “parente” pour ne pas perdre les métadonnées.

Corriger les métadonnées existantes

Les gars de chez Olympus sont des em*****urs 😁 :

  • sur mes deux appareils de cette marque, l'un indique “OLYMPUS IMAGING CORP.” comme fabricant et le second “OLYMPUS CORPORATION” (déjà c'est moche dans les deux cas avec toutes ces majuscules et ensuite les deux appellations différentes n'aident pas pour faire d'éventuelles requêtes dans une base de données)
  • le titre et la description de base des photos sont toujours “OLYMPUS DIGITAL CAMERA” ce qui me hérisse le poil (cette information n'a rien à faire là, c'est de la pollution publicitaire, et je ne met pas de titre ou de description pour chaque photo or si j'oublie de les mettre à blanc, je n'ai pas envie de voir çà sous chaque photo)

D'autre part, certains appareils dotés d'une optique intégrée (ou tous ?) n'ajoutent aux clichés aucuns détails concernant celle-ci (c'est le cas de notre Panasonic Lumix DMC-FZ200 et de l'Olympus Stylus Tough TG-4).

Voici un petit script qui rectifie tout cela dans toutes les photos aux formats supportés par exiftool (pas de fioritures et je n'ai fait aucun effort pour les caractères accentués erronés et attention si le chemin à traîter contiens des espaces 😎) :

exiftool_constructeurs.bat
@echo off
echo Corrections des metadonnées des constructeurs.
echo Pour tous les Olympus: fabricant inconsistant, marque en description et titre.
echo Pour le Olympus TG-4: modèle d'objectif manquant.
echo Pour le Panasonic DMC-FZ200: modèle d'objectif manquant.
echo Pour le Fujifilm X-T2: passage en minuscules de la marque.
 
rem Teste si le chemin est passé en paramètre
if EXIST %~1 (set CHEMIN=%1) else goto QuestionChemin
if "%CHEMIN%" == "" goto QuestionChemin
goto Suite
 
:QuestionChemin
echo.
set /p CHEMIN=Quel chemin faut-il traîter ? 
echo.
if %CHEMIN:~-1%==\ (
			echo Recommence sans le dernier backslash
			echo.
			goto QuestionChemin
	             ) 
if exist "%CHEMIN%" goto suite
echo.
echo Chemin non valide
echo %CHEMIN% n'existe pas
echo.
goto QuestionChemin
 
:Suite
if "%CHEMIN%" == "" goto QuestionChemin
echo.
echo Traitement des images dont la marque est OLYMPUS CORPORATION et le moèdele est TG-4
"%AppData%\GeoSetter\tools\exiftool.exe" -m -r -if "$make eq 'OLYMPUS CORPORATION' && $model eq 'TG-4'" -make="Olympus" -imagedescription="" -description="" -LensInfo="25-100mm f/4.5-18" -overwrite_original "%CHEMIN%"
echo.
echo Traitement des images dont la marque est OLYMPUS IMAGING CORP. et le modèle est E-PM1
"%AppData%\GeoSetter\tools\exiftool.exe" -m -r -if "$make eq 'OLYMPUS IMAGING CORP.' && $model eq 'E-PM1'" -make="Olympus" -imagedescription="" -description="" -overwrite_original "%CHEMIN%"
echo.
echo Ajout du modèle de l'objectif intégré au DMC-FZ200.
"%AppData%\GeoSetter\tools\exiftool.exe" -m -r -if "$model eq 'DMC-FZ200'" -Lens="LEICA DC VARIO-ELMARIT (Nano Surface Coating)" -LensModel="LEICA DC VARIO-ELMARIT (Nano Surface Coating)" -LensType="LEICA DC VARIO-ELMARIT (Nano Surface Coating)" -LensInfo="25-600mm f/2.8" -overwrite_original "%CHEMIN%"
echo.
echo Traitement des images dont la marque est FUJIFILM et le moèdele est X-T2
"%AppData%\GeoSetter\tools\exiftool.exe" -m -r -if "$make eq 'FUJIFILM' && $model eq 'X-T2'" -make="Fujifilm" -overwrite_original "%CHEMIN%"
 
:fin
echo.
pause

Commandes basiques

Lecture des métadonnées existantes d'une photo

"%AppData%\GeoSetter\tools\exiftool" -a "C:\chemin\vers\mon_image.jpg"

Pour exporter directement le résultat vers un fichier txt, utiliser simplement une redirection :

"%AppData%\GeoSetter\tools\exiftool" -a "C:\chemin\vers\mon_image.jpg" > "C:\mon_image.txt"

Commandes complexes

Copier les métadonnées d'une image vers une autre

"%AppData%\GeoSetter\tools\exiftool" -overwrite_original -tagsfromfile "C:\chemin\source.jpg" "C:\chemin\destination.jpg"

ou plutôt :

"%AppData%\GeoSetter\tools\exiftool" -TagsFromFile C:\Users\Simon\Desktop\2016-07-16_14-42-30_P7162440.jpg -all:all T:\PHOTOS\2016\07\16\2016-07-16_14-42-30_P7162440.dng

voire (pour inclure les metadonnées pouvant affecter le rendu de l'image comme l'espace de couleur) :

"%AppData%\GeoSetter\tools\exiftool" -TagsFromFile C:\Users\Simon\Desktop\2016-07-16_14-42-30_P7162440.jpg -all:all -unsafe T:\PHOTOS\2016\07\16\2016-07-16_14-42-30_P7162440.dng
logiciels/exiftool.txt · Dernière modification: 2017/08/19 06:48 par Simon